//	example path
//	InitWaveOutput
//	{
//		Target wave_start_relay
//		Action runscriptcode
//		Param "if(!(`CreateParaTankPath` in this)) IncludeScript(`paratank_lite`)
//
//		if(!(Entities.FindByName(null,`paratank_1`))) {
//			CreateParaTankPath([
//				`964 0 512|paratank_1`,
//				`137 0 -128|paratank_2_ground`, // _ground retracts the parachute
//				`-1372 0 -128|paratank_3`
//			])
//		}"
//	}

function CreateParaTankPath(array) {
	local arraylen = array.len()-1
	for(local i=arraylen;i>=0;i--) {
		local info = split(array[i],"|")
		local pos = info[0]
		local name = info[1]
		local nextname = ""
		if(i<arraylen) {
			local nextinfo = split(array[i+1],"|")
			nextname = nextinfo[1]
		}
		local path = SpawnEntityFromTable("path_track",{
			origin = pos
			targetname = name
			target = nextname
			orientationtype = 1
		})
		if(i==0)
			path.KeyValueFromString("OnPass","wave_start_relay,CallScriptFunction,SetParaTank,-1,-1")
		else if(name.tolower().find("_ground"))
			path.KeyValueFromString("OnPass","wave_start_relay,CallScriptFunction,DestroyParaTank,-1,-1")
	}
}
::worldspawn <- Entities.FindByClassname(null,"worldspawn")
function SetParaTank() {
	// activator is tank_boss
	// caller is path_track
	if(activator.GetClassname()!="tank_boss") return
	
	local snd = {
		sound_name = "items/para_open.wav"
		entity = worldspawn
		filter = 5
		pitch = 85
	}
	PrecacheSound(snd.sound_name)
	EmitSoundEx(snd)

	for(local child=activator.FirstMoveChild();child!=null;child=child.NextMovePeer())
		if(child.GetModelName().find("tank_track"))
			EntFireByHandle(child,"SetAnimation","ref",-1,null,null)

	activator.ValidateScriptScope()
	local gss = activator.GetScriptScope()

	activator.SetAbsAngles(QAngle(0,activator.GetAbsAngles().y,0))
	local tankspeed = NetProps.GetPropFloat(activator,"m_speed")
	gss.paratanktrain <- SpawnEntityFromTable("func_tracktrain",{
		origin = caller.GetOrigin()
		speed = tankspeed
		startspeed = tankspeed
		target = caller.GetName()
	})
	activator.KeyValueFromString("OnKilled","!self,RunScriptCode,if(blimptrain.IsValid())blimptrain.Kill(),-1,-1")
	local chute = SpawnEntityFromTable("prop_dynamic",{
		origin = activator.GetOrigin()
		model = "models/props_aircrap/tank_chute.mdl"
		defaultanim = "deploy"
	})
	gss.chute <- chute
	EntFireByHandle(chute,"SetParent","!activator",-1,activator,null)
	EntFireByHandle(chute,"SetDefaultAnimation","idle",-1,null,null)
	AddThinkToEnt(activator,"ParaTankThink")
}
function DestroyParaTank() {
	local gss = activator.GetScriptScope()
	if(!gss)return

	local snd = {
		sound_name = "items/para_close.wav"
		entity = worldspawn
		filter = 5
		pitch = 85
	}
	PrecacheSound(snd.sound_name)
	EmitSoundEx(snd)

	for(local child=activator.FirstMoveChild();child!=null;child=child.NextMovePeer())
		if(child.GetModelName().find("tank_track"))
			EntFireByHandle(child,"SetAnimation","forward",-1,null,null)

	AddThinkToEnt(activator,null)
	gss.paratanktrain.Kill()
	EntFireByHandle(gss.chute,"SetAnimation","retract",-1,null,null)
	EntFireByHandle(gss.chute,"AddOutput","OnAnimationDone !self:Kill:-1:-1",0,null,null)
}

::ParaTankThink <- function() {
	self.SetAbsOrigin(paratanktrain.GetOrigin())
	self.GetLocomotionInterface().Reset()
	return -1
}